武器が壊れるようにしてみた

武器が劣化するサンプル (papyrus)

Scriptname SampleScript Extends Quest

Actor Property PlayerRef Const Auto Mandatory

ObjectMod Z_mod_Condition_Standard_1_Degraded1
ObjectMod Z_mod_Condition_Standard_2_Degraded2
ObjectMod Z_mod_Condition_Standard_3_Degraded3
ObjectMod Z_mod_Condition_Standard_4_Degraded4
ObjectMod Z_mod_Condition_Standard_D_Destroyed


Function Initialize()
    RegisterForRemoteEvent(PlayerRef, "OnPlayerLoadGame")
EndFunction


Function Initialize2()
    if Game.IsPluginInstalled("Z_Horizon.esp")
        GoToState("HORIZON_READY")
    else
        GoToState("HORIZON_NOT_READY")
    endif
EndFunction


Function ShowActorWeapon(Actor akTarget)
    ObjectMod[] kOmodList = akTarget.GetWornItemMods(41)

    if !kOmodList
        Debug.Trace("ShowActorWeapon " + akTarget + " no weapon omod found")
        return
    endif

    Int i = kOmodList.Length

    while i > 0
        i -= 1
        ObjectMod kOmod = kOmodList[i]
        Debug.Trace("omod " + i + " " + kOmod)

        ObjectMod:PropertyModifier[] kProperties = kOmod.GetPropertyModifiers()
        Int j = kProperties.Length

        while j > 0
            j -= 1
            Debug.Trace(" properties " + j)
            Debug.Trace(" target = " + kProperties[j].target)
            Debug.Trace(" operator = " + kProperties[j].operator)
            Debug.Trace(" object = " + kProperties[j].object)
            Debug.Trace(" value1 = " + kProperties[j].value1)
            Debug.Trace(" value2 = " + kProperties[j].value2)
        endwhile
    endwhile
EndFunction


Function TryToBreakWeapon(Actor akTarget, Int aiBipedSlot)
    Form kWeapon = akTarget.GetEquippedWeapon(0)

    if !kWeapon
        Debug.Trace("TryToBreakWeapon " + akTarget + " no weapon equipped")
        return
    endif

    ObjectMod[] kOmodList = akTarget.GetWornItemMods(aiBipedSlot)

    if !kOmodList
        Debug.Trace("TryToBreakWeapon " + akTarget + " " + kWeapon + " no weapon omod found")
        return
    endif

    if kOmodList.Find(Z_mod_Condition_Standard_D_Destroyed) != -1
        Debug.Trace("TryToBreakWeapon " + akTarget + " " + kWeapon + " is already destroyed")
    elseif kOmodList.Find(Z_mod_Condition_Standard_4_Degraded4) != -1
        akTarget.UnequipItem(kWeapon, abSilent = true)
        akTarget.AttachModToInventoryItem(kWeapon, Z_mod_Condition_Standard_D_Destroyed)
        Debug.Trace("TryToBreakWeapon " + akTarget + " " + kWeapon + " is destroyed")
        Debug.Notification(kWeapon.GetName() + "は壊れた")
    elseif kOmodList.Find(Z_mod_Condition_Standard_3_Degraded3) != -1
        akTarget.AttachModToInventoryItem(kWeapon, Z_mod_Condition_Standard_4_Degraded4)
        Debug.Trace("TryToBreakWeapon " + akTarget + " " + kWeapon + " is degraded 4")
        Debug.Notification(kWeapon.GetName() + "は劣化した")
    elseif kOmodList.Find(Z_mod_Condition_Standard_2_Degraded2) != -1
        akTarget.AttachModToInventoryItem(kWeapon, Z_mod_Condition_Standard_3_Degraded3)
        Debug.Trace("TryToBreakWeapon " + akTarget + " " + kWeapon + " is degraded 3")
        Debug.Notification(kWeapon.GetName() + "は劣化した")
    elseif kOmodList.Find(Z_mod_Condition_Standard_1_Degraded1) != -1
        akTarget.AttachModToInventoryItem(kWeapon, Z_mod_Condition_Standard_2_Degraded2)
        Debug.Trace("TryToBreakWeapon " + akTarget + " " + kWeapon + " is degraded 2")
        Debug.Notification(kWeapon.GetName() + "は劣化した")
    else
        akTarget.AttachModToInventoryItem(kWeapon, Z_mod_Condition_Standard_1_Degraded1)
        Debug.Trace("TryToBreakWeapon " + akTarget + " " + kWeapon + " is degraded 1")
        Debug.Notification(kWeapon.GetName() + "は劣化した")
    endif
EndFunction


Event OnQuestInit()
    Initialize()
    Initialize2()
EndEvent


Event Actor.OnPlayerLoadGame(Actor akActorRef)
    Initialize2()
EndEvent


State HORIZON_READY
    Event OnBeginState(string asOldState)
        Z_mod_Condition_Standard_1_Degraded1 = Game.GetFormFromFile(0x12490E, "Z_Horizon.esp") as ObjectMod
        Z_mod_Condition_Standard_2_Degraded2 = Game.GetFormFromFile(0x12491F, "Z_Horizon.esp") as ObjectMod
        Z_mod_Condition_Standard_3_Degraded3 = Game.GetFormFromFile(0x12490F, "Z_Horizon.esp") as ObjectMod
        Z_mod_Condition_Standard_4_Degraded4 = Game.GetFormFromFile(0x124920, "Z_Horizon.esp") as ObjectMod
        Z_mod_Condition_Standard_D_Destroyed = Game.GetFormFromFile(0x124910, "Z_Horizon.esp") as ObjectMod

        RegisterForAnimationEvent(PlayerRef, "reloadComplete")
        RegisterForAnimationEvent(PlayerRef, "weaponSwing")

        RegisterForHitEvent(PlayerRef, aiBlockFilter = 1)
    EndEvent


    Event OnAnimationEvent(ObjectReference akSource, string asEventName)
        if asEventName == "weaponSwing"
            if Utility.RandomInt(1, 100) == 1
                TryToBreakWeapon(akSource as Actor, 33)
            endif
        else
            if Utility.RandomInt(1, 50) == 1
                TryToBreakWeapon(akSource as Actor, 41)
            endif
        endif
    EndEvent

    Event OnHit(ObjectReference akTarget, ObjectReference akAggressor, Form akSource, Projectile akProjectile, bool abPowerAttack, \
        bool abSneakAttack, bool abBashAttack, bool abHitBlocked, string apMaterial)

        if Utility.RandomInt(1, 50) == 1
            TryToBreakWeapon(akTarget as Actor, 33)
        endif

        RegisterForHitEvent(akTarget, aiBlockFilter = 1)
    EndEvent
EndState


State HORIZON_NOT_READY
    Event OnBeginState(string asOldState)
        UnregisterForAnimationEvent(PlayerRef, "reloadComplete")
        UnregisterForAnimationEvent(PlayerRef, "weaponSwing")

        UnregisterForAllHitEvents()
    EndEvent
EndState